Function OGM(sWaarde As String) As String
'voorbeeld OGM-nummer: +++785/4279/40359+++
'Bron: https://www.oplossing.be/excel/berekenen-van-een-ogm-digit/new/?topicseen#new
Const iDELER As Integer = 97
Dim sCheckDigit As String
Dim Opmaak As String
Dim y, z As String
Dim Digits As String

'Commentaar OGM
' Een overschrijving met gestructureerde mededeling is een overschrijving
'waarvan de mededeling bestaat uit een groep van drie, een groep van vier
'en een groep van vijf cijfers, gescheiden door een schuine streep.
'je kan plustekens(+++) of (***) vóór de eerste groep en na de laaste groep cijfers meegeven.
'De eerste 10 cijfers van het OGM kan jezelf bepalen.
'De laatste 2 cijfers van het OGM zijn gereserveerd voor het controlegetal.
'In totaal zijn er 12 getallen in het OGM met het controlegetal inbegrepen.
'De OGM functie werkt bij minimum 1 cijfer of tot maximum 10 cijfers invullen(sWaarde)

  If Len(sWaarde) > 10 Or sWaarde = 0 Then Exit Function

 
    ' de MOD functie breekt af bij een Long Integer (=2147483648) = Bug van VBA!!!! Daarom onderstaande formule...
    sCheckDigit = Format(sWaarde - (iDELER * Int(sWaarde / iDELER)), "00")
    ' Opmaken van het ogm nummer
    OGM = Format(sWaarde & IIf(sCheckDigit = "00", 97, sCheckDigit), "+++000/0000/00000+++")
   
   
   
End Function



Alleen nog regel toevoegen wanneer sWaarde leeg is. In Excel weet ik het niet hoe foutmelding kan opgevangen worden.

Vriendelijke groeten,

Diezel

Bedankt voor de snelle reactie.

Die code klopt volgens mij niet:

De code geeft dit als resultaat voor het nummer : 105100112 --> +++010/5100/11230+++

Het resultaat zou moeten zijn: +++105/1001/12009+++

Function OGM(Optional ByVal sWaarde As String = 0) As String

'Bron: https://www.oplossing.be/excel/berekenen-van-een-ogm-digit/new/?topicseen#new
'VBA UDF code bijgewerkt door Diezel
Const iDELER As Integer = 97
Dim sCheckDigit As String
Dim I As Integer

'Commentaar OGM
' Een overschrijving met gestructureerde mededeling is een overschrijving
'waarvan de mededeling bestaat uit een groep van drie, een groep van vier
'en een groep van vijf cijfers, gescheiden door een schuine streep.
'je kan plustekens(+++) of (***) vóór de eerste groep en na de laaste groep cijfers meegeven.
'De eerste 10 cijfers van het OGM kan jezelf bepalen.
'De laatste 2 cijfers van het OGM zijn gereserveerd voor het controlegetal.
'In totaal zijn er 12 getallen in het OGM met het controlegetal inbegrepen.
'De OGM functie werkt bij minimum 1 cijfer of tot maximum 10 cijfers invullen(sWaarde)
   
   'Vult men niks is dan zal optional een 0 geven en kunnen we de procedure verlaten.
   If sWaarde = 0 Then Exit Function

   'Vult men meer dan 10 cijfers in dan verlaten we de procedure.
   If Len(sWaarde) > 10 Then Exit Function

   'Indien OGM minder dan 10 cijfers dan zetten we nullen achter het cijfer zolang we aan 10 cijfers komen:

   For I = Len(sWaarde) To 9
   sWaarde = sWaarde & "0"
   Next I

 
    ' de MOD functie breekt af bij een Long Integer (=2147483648) = Bug van VBA!!!! Daarom onderstaande formule...
    sCheckDigit = Format(sWaarde - (iDELER * Int(sWaarde / iDELER)), "00")
    ' Opmaken van het ogm nummer
    OGM = Format(sWaarde & IIf(sCheckDigit = "00", 97, sCheckDigit), "+++000/0000/00000+++")

End Function

AllroundITer: Nu zal het wel juist zijn voor het OGM nr 105100112. Zelfs bij OGM 1 Deze code is nu wel ok zoals in jou uisnede ahoewel ik geen expert ben in Excel. Wel in vba Acces en daar doet deze code het prima.
Toetsing van de UDF VBA code: https://www.gestructureerdemededeling.be/
Het probleem lag hem indien lager dan 10 digits dan worden er geen voorloopnullen gezet maar achterloopnullen na het getal zolang we aan 10 digits komen.
Met for next zetten we er nullen achter hé.

AllrroundITer, het is enkel bij factuurnummer 1051001120 dat je als OGM +++105/1001/12009+++ krijgt. Anders is het giswerk in de zin van al dan niet voorloopnullen te gebruiken of na het factuurnummer in jou voorbeeld van het 9 cijferige factuurnummer wat giswerk te doen wat het 10de getal zal worden. dus volgens de regels worden voorloopnullen geplaatst indien het OGM nummer kleiner is dan 10. Indien je geen voorloopnullen zou gebruiken wanneer dit nodig is(eerste groep <100) dan zou de eerste drie getallen uit deze groep minstens 100 of meer zijn en geen lagere getallen(<100) voor de eerste drie getallen uit de eerste groep kunnen verkrijgen. Besluit: je zal nog héél wat verkopen mogen genereren om aan factuurnummer 1051001120 te komen. Vriendelijke groeten, Diezel

Hallo Diezel,

Ben jij het nu niet heel ver aan het zoeken?
Volgens mij is de essentie dat iemand in principe een getal van maximaal 10 cijfers ingeeft en er een OGM van gemaakt wordt. Doet hij/zij dat niet, dan mag er volgens mij een foutmelding volgen. Dat is wat mijn code uit #31 doet, en dan durf ik verwachten dat de gebruiker een nieuwe poging onderneemt.
Heb je dat op die manier geprobeerd? En wat kan/moet volgens jou beter?
Mocht het nodig zijn (maar we horen totaal niets meer van AllroundITer...) om voorloopnullen door achterloopnullen te vervangen, dan vraagt dat slechts een kleine aanpassing.

Mvg,
Molly

Hallo Molly en diezel,

Molly, je laatste Function kijkt wel of sWaarde een geheel en positief getal is.
Maar ze voegt geen voorloopnullen toe als Lengte sWaarde < 10
En dat was toch de originele vraag van TS.

Tijdens mijn lange periode als zelfstandige heb ik van mijn boekhouder vaak de melding gekregen dat als ik een gestructureerde mededeling mee gaf bij een factuur, dat het geen bal uitmaakte of die nullen voor of na de < 10 mededeling stonden.
Als ik een nieuw boekhoudingsjaar (bvb 2005) begon, dan gebruikte ik steeds 2005000001,2005000002,2005000003, enzovoort als factuurnummer. Binnen mijn Excel facturatieprogramma zorgde ik voor automatisch beperken tot 10 digits.

Waar die nullen staan maakt niets uit, zolang de klant deze OGM gebruikt weet ik waar de betaling op slaat.
En het controlegetal klopt (moet wel kloppen) altijd indien de regel van rest van deling door 97 wordt toegepast.

Just my 2 cents... 

SoftAid              

Hallo SoftAid,

Molly, je laatste Function kijkt wel of sWaarde een geheel en positief getal is.
Maar ze voegt geen voorloopnullen toe als Lengte sWaarde < 10

Gokje: heb je enkel de code bekeken maar ze niet geprobeerd? 

Mvg,
Molly

Public Function OGM(Optional ByVal dWaarde As Double = 0) As String

'Auteur: VBA UDF code geschreven door Diezel van Oplossing.be
'Datum: woensdag 5 oktober 2022 13:42
'Last Update:
'Benaming functie OGM: Overschrijving met Gestructureerde Mededeling.
'Doelstelling functie:
'1/Vrijë keuze om maximum de eerste 10 cijfers van dWaarde te bepalen.
'2/Berekenen sCheckDigit en zet sCheckDigit na de dWaarde.
'3/valideerbaar uniek OGM nummer.
'4/Indien nodig voorloopnullen plaatsen bij opmaak OGM nummer.
'Creatie, controle van OGM
'Toetsing van de code kan je online met de Belgische OGM tool.
'Tool: https://www.gestructureerdemededeling.be/

'Commentaar OGM
'Een overschrijving met gestructureerde mededeling is een overschrijving
'waarvan de mededeling bestaat uit een groep van drie, een groep van vier
'en een groep van vijf cijfers, gescheiden door een schuine streep.
'je kan plustekens(+++) of (***) vóór de eerste groep en na de laaste groep cijfers meegeven.
'Je kan tot maximum 10 cijfers van het OGM zelf bepalen.
'Dit kan een klantnummer, factuurnummer of een combinatie van wat jezelf wil.
'De laatste 2 cijfers van het OGM zijn gereserveerd voor sCheckDigit.
'In totaal zijn er maximum 12 getallen in het OGM met sCheckDigit inbegrepen.
'De OGM functie werkt bij minimum 1 cijfer of tot maximum 10 cijfers invullen/uitlezen(dWaarde).
'Indien OGM nummer minder dan 10 cijfers bevat zal bij opmaak dWaarde voorloopnullen opgemaakt worden.
'Voorbeeld: 651055492 met sCheckDigit 28 geeft als opmaak +++065/1055/49228+++
'Voorbeeld: 20779775 met sCheckDigit 47 geeft als opmaak +++002/0779/77547+++
'Voorbeeld: 190601380 met sCheckDigit 66 geeft als opmaak +++019/0601/38066+++
'Voorbeeld: 9999999999 met sCheckDigit 48 geeft als opmaak +++999/9999/99948+++
'Voorbeeld: 0 dit gebruiken we niet met sCheckDigit 97 geeft als opmaak +++000/0000/00097+++
'Voorbeeld: 1 met sCheckDigit 01 geeft als opmaak +++000/0000/00101+++

'Declaratiesectie van de variabelen:
Dim sCheckDigit As String
 
    'We vragen aan de functie Controlegetal de sCheckDigit.
    sCheckDigit = Format(Controlegetal(CDbl(dWaarde)), "00")
   
    'Opmaken van het OGM nummer
    OGM = Format(dWaarde & sCheckDigit, "+++000/0000/00000+++")
   
End Function

Private Function Controlegetal(ByVal dWaarde As Double) As String
'Auteur: VBA UDF code geschreven door Diezel van Oplossing.be
'Datum: woensdag 5 oktober 2022 13:59
'Last Update:
'Benaming functie OGM: Controlegetal - CheckDigits laatste 2 cijfers.
'Doelstelling functie: Genereer een geldig Controlegetal
'Het berekenen van de sleutel van dWaarde, het controlegetal

'Declaratie van de variabelen:
Dim A As Double
Dim B As Double
Dim C As Double
Dim D As Double
Dim E As Double

 
    A = dWaarde 'Factuurnummer; klantnummer;...
    B = A / 97 'delen
    C = Int(B) 'coëfficiënt - Stuurt een integer zonder ","
    D = C * 97 'vermenigvuldigen
    E = A - D  'Controlegetal OGM

    If E = 0 Then E = 97
    Controlegetal = Format(E, "00")
       
End Function

Heb mijn eigen versie van gemaakt maar met variabele dWaarde als Double ipv variabele String of variant