Beste  ;)

Graag zou ik van 2 formules één formule willen in elkaar steken in voorwaardelijke opmaak, maar ik kom er niet uit  ???

De formules zijn:=EN(E$10<>"";WEEKDAG(E$10;2)>5)
De andere is :=EN(VERGELIJKEN(D$10;$L$75:$L$87;0);D$15="zo")

Wil het volgende, kleur de weekends en kleur de maandag na een feestdag.

Beide formules werken apart, maar aan gebrek aan voorwaardelijke opmaak (heb er meer dan drie nodig) wil ik deze samenvoegen, aangezien ze dezelfde opmaak hebben.

Groetjes Danny

Hallo Danny,

zoals de opmaak nu staat, zijn het 2 verschillende voorwaarden.
Als de eerste oude voorwaarde van toepassing is, wordt er een kleur gegeven.
Als de eerste niet, maar de tweede wel van toepassing is, wordt er ook een kleur gegeven. Dit is wat jij wilt.

De functie EN is enkel van toepassing als aan alle voorwaarden wordt voldaan.

Als je de twee voorwaarden dus gaat samenvoegen (vraag me niet hoe) dan zal er enkel een kleur gegeven worden indien aan alle voorwaarden voldaan wordt, niet meer aan je eerste oude of tweede oude voorwaarde apart, maar aan beide oude voorwaarden.

Ik denk dat je dan nog niet verder bent.... 

Kan je niet beter de functie OF gebruiken?

SoftAid        

Hallo,

Vraag1
Met welk formuleresultaat wordt voorwaardelijke opmaak geactiveerd?
Vraag2
Maak een lijstje van de resultaten die je kan bekomen met
=EN(E$10<>"";WEEKDAG(E$10;2)>5)
Vraag3
Maak een lijstje van de resultaten die je kan bekomen met
:=EN(VERGELIJKEN(D$10;$L$75:$L$87;0)$15="zo")
Vraag4
Welke resultaten kan je dan bekomen door de twee formules samen te zetten?
=OF(eersteformule;tweedeformule)

Antwoorden 1 to 4
1. WAAR
2. WAAR, ONWAAR, #WAARDE (als je bijvoorbeeld tekst tijpt in de cel die de weekdat moet vinden)
3. WAAR, ONWAAR, #ISNB (wanneer "vergelijken" niets oplevert), andere fouten naargelang de inhoud van de broncellen
4. combinaties van 2. en 3.

Vraag 5
Wat is het resultaat van
=OF(formula1; formula2)
met formula1: WAAR & formula2: #ISNB
Jammer genoeg is dit #ISNB
Antwoord
Dus als 1 van beide een fout genereert, blijft die fout doorwerken in je resultaat. Dan krijg je dus niet WAAR en dus ook geen correcte opmaak.

Tot zover de oorzaak van je probleem.

TIP:
Voor foutopsporing bij voorwaardelijk opmaak is het aangewezen om de formules in cellen te zetten. Als je de samengestelde formule in een cel had gezet, had je misschien de oorzaak gevonden.

Oplossing:
We willen die #ISNB kwijtraken en omzetten naar ONWAAR. Dat kan bijvoorbeeld met NIET(ISNB(...

Selecteer C4:R11 en gebruik deze formule
=OF(EN(C$4<>"";WEEKDAG(C$4;2)>5);EN(NIET(ISNB(VERGELIJKEN(B$4;$D$20:$D$32;0)));B$5="zo"))

beste groeten,
Erik

Graag gedaan.
Vraag me niet hoe die spatie daar gekomen is

Ik zie nu nog een mogelijke verbetering = kortere, dus snellere formule.
=EN(C$4<>"";WEEKDAG(C$4;2)>5)
kan naar mijn gedacht vervangen worden door
=WEEKDAG(C$4;3)>4

volledige formula is dan
=OF(WEEKDAG(C$4;3)>4;EN(NIET(ISNB(VERGELIJKEN(B$4;$D$20:$D$32;0)));B$5="zo"))
mijn hoofd is wat moe
NIET(ISNB kan natuurlijk nog vervangen worden door ISGETAL
=OF(WEEKDAG(C$4;3)>4;EN(ISGETAL(VERGELIJKEN(B$4;$D$20:$D$32;0));B$5="zo"))
zo... weer een stuk er af en sneller

selecteer C4:R11
C4 moet actief zijn (dus wanneer je selecteert in C4 beginnen)
dan formule in voorwaardelijke opmaak plakken + OK
=OF(WEEKDAG(C$4;3)>4;EN(ISGETAL(VERGELIJKEN(B$4;$D$20:$D$32;0)); B$5="zo"))'k heb zonet de formule uit bovenstaand bericht gekopieerd: werkt voor mij