***UPDATE*** (extra vraag)


Ik ben nu voor de 2e dag op rij bezig met de 2e pagina van de multipage, nog steeds met de optie “alleenstaand”.
Zowel bij “alleenstaand” als bij “samenwonend” zijn er diverse scenario’s mogelijk die elk met een ander 1e frame zullen starten.
Vanaf het 2e frame kunnen de frames in hoogte verschillen afhankelijk van de gegevens in het vorige frame. De .top positie van een volgend frame wordt dan in dit geval ook altijd bepaald op basis van de hoogte van het vorige frame (dus .top huidige frame = .top + .height vorige frame + tussenruimte).
Door de diverse mogelijke scenario’s zal de hoogte van de multipage-pagina soms onvoldoende zijn voor alle frames voor dat betreffende scenario.
Om in dit geval niet telkens een tweede multipage-pagina te moeten maken voor dezelfde optie dacht ik om eventueel bij bereik van het ‘einde’ van de multipage-pagina deze te ‘clearen’ door de reeds verwerkte frames opnieuw ‘buiten zicht’ te plaatsen zodat het volgende frame opnieuw bovenaan komt.

Vanaf het tweede frame is er rechtsonder in het frame telkens een klein label(knop) voorzien met “>>>” als .caption zodat, via tussenkomst gebruiker, vba weet dat het volgende frame getoond moet worden.

Om globaal naar een volgende multipage-pagina te gaan voorzie ik onderaan de multipage-pagina een commandbutton “volgende” die pas ‘binnen beeld’ gezet wordt zodra het laatste frame verwerkt wordt.

Concreet zou ik dus, indien 1 multipage-pagina lengte onvoldoende zou zijn, bij bereik van het einde van de pagina een aparte commandbutton (volgende deel) ‘binnen beeld’ willen plaatsen om aan te tonen dat alle reeds verwerkte frames terug ‘buiten beeld’ gezet moeten worden en dat het volgende frame bovenaan geplaatst moet worden.

Hoe, en vooral waar, kan ik dit best in mijn code verwerken?

Groetjes,
BlackDevil/Bieke

Hey Bieke,

Vergis ik me nu dat ik gisteren, vooraleer te moeten vertrekken, in een flits nog een andere post heb zien passeren die ondertussen terug verdwenen is?
In dat geval is het waarschijnlijk goed nieuws, want dan heb je het zelf in orde gekregen

Wat je huidige vraag (+ daaropvolgende eigen suggestie) betreft: van radicale uitspraken onthou ik me liever, maar op het eerste zicht zou ik denken dat je daarmee met grote waarschijnlijkheid in de goede richting zit.
Veel verliezen met het eens te proberen zal je wel niet

Groetjes,
Molly

Goeienamiddag iedereen,

Ik heb nog eens een vraagje, ditmaal omtrent een hulpmiddeltje (sub) dat ik gemaakt heb mbt het ontwerp van dit project.

Omdat ik (bijna) alle controls in de UF een eigen (genummerde) naam geef en alle controls reeds op voorhand maak heb ik dus al héél wat namen gecreëerd.
Om een beetje het overzicht te kunnen behouden heb ik een codeblokje opgebouwd om alle namen van deze controls weg te schrijven in een werkblad (“ctrl-namen”) per multipage-pagina en per frame.
De code werkt perfect maar omdat ik nog niet alle multipage-pagina’s heb gemaakt moet ik wel telkens per multipage-pagina mijn code gaan aanpassen wat betreft het multipage-pagina-nummer en het kolom-nr én moet ik naderhand op het werkblad ook nog eens handmatig de hoofdtitels (rij 1) invoeren en in elke kolom de controls-namen alfabetisch gaan sorteren.
In rij 1 komt dus telkens de hoofdtitel in formaat : “Multipage1.” & paginanaam
In rij 2 komen dan de namen van de frames (dus elk framenaam in de volgende kolom)
En vanaf rij 3 komen dan alle namen van de controls van het betreffende frame in dezelfde kolom.

Hoe kan ik best mijn code aanpassen dat hij enerzijds alle multipage-paginas doorloopt, de titel voor de multipage-pagina in de juiste kolom zet (dus de tweede titel in de kolom na het laatste frame van de eerste titel, enz…) én dat hij dan per kolom vanaf rij 3 alles alfabetisch sorteert?

Dit is mijn code-blokje ingesteld voor de allereerste pagina (“multipage1.pages(0)”) :
Sub getnamen()
  Dim frm As Object, ctrl As Object, frij As Long, crij As Long, kol As Long
  With Sheets("ctrl-namen")
    kol = 0
    For Each frm In UserForm1.MultiPage1.Pages(0).Controls
      If TypeName(frm) = "Frame" Then
        kol = kol + 1
        frij = 2
        .Cells(frij, kol) = frm.Name
        crij = 2
        For Each ctrl In frm.Controls
          crij = crij + 1
          .Cells(crij, kol) = ctrl.Name
        Next
      End If
    Next
  End With
End Sub

Alvast bedankt op voorhand.

Groetjes,
BlackDevil/Bieke

Nog rap-rap

Misschien rond je bestaande lus nog een andere:
For Each pagina In UserForm1.MultiPage1.Pages
Groetjes,
Molly

***UPDATE***

En met nog een klein extraatje erbij (dat ik persoonlijk iets duidelijker/overzichtelijker vind) heb ik het meteen in je laatste bestand geplakt

Groetjes,
Molly

***UPDATE***

En met nog een klein extraatje erbij (dat ik persoonlijk iets duidelijker/overzichtelijker vind) heb ik het meteen in je laatste bestand geplakt

Groetjes,
Molly

Net bekeken 
de toevoeging  "miltipage1" aan de titel had ik er zelf reeds aan toegevoegd (had dit reeds bij de nog handmatige invoer ook zo gedaan).
De autofit voor de kolommen die was ik eventjes vergeten dus bedankt mij eraan te herinneren 

groetjes,
Bieke

Hey Bieke,

Kleine rechtzetting om te beginnen?

Ik heb namelijk multipage-pagina's waarbij het eerste frame het volgnummer "0" heeft en met de huidige code komt dit dan als laatste
in de 'for each--'-loop waardoor het in de laatste kolom voor de betreffende pagina komt te staan

Dat komt niet omwille van de '0' maar omdat dat het laatst aangemaakte frame is dat hernoemd is. Anders gezegd: als je een eerste frame Frame0 zou noemen en daarna meer frames toevoegen zou Frame0 wél als eerste aan bod komen.

Daar heb je voor je recentste wens niet veel aan, dus sorteren dan maar. Om niet je ganse code overhoop te moeten halen heb ik het maar pragmatisch aangepakt, dus volgende code mag je gewoon invoegen, onmiddelijk na je regel met de eerste 'merge'-instructie:
kolommen = (fkol - pkol) + 1
If kolommen > 1 Then
  rijen = .UsedRange.Rows.Count - 2
  ReDim sort_kol(1 To kolommen)
  For i = 1 To kolommen
    sort_kol(i) = Join(Application.Transpose(.Cells(3, pkol + i - 1).Resize(rijen)), "|")
  Next i
  For i = 1 To kolommen - 1
    For ii = i + 1 To kolommen
      If sort_kol(ii) < sort_kol(i) Then
        tmp = sort_kol(i)
        sort_kol(i) = sort_kol(ii)
        sort_kol(ii) = tmp
      End If
    Next ii
  Next i
  For i = 1 To kolommen
    arr = Split(sort_kol(i), "|")
    .Cells(3, pkol + i - 1).Resize(rijen) = Application.Transpose(arr)
  Next i
End If

Groetjes,
Molly

Hey Bieke,

MAAR mijn onderste borders bij de ctrl-namen zelf kloppen nu natuurlijk wel niet meer.
Kan dit in de code nog simpel opgevangen worden of moet het hele blok dan toch maar 'herschreven' worden?

Dat gaan we niet doen, hé, hoogstens wat code verschuiven en een kleinigheid toevoegen.
Jouw ogen zullen wel anders werken dan de mijne, want even ging het woord 'spielerei' door me heen, maar dat zal dan waarschijnlijk komen omdat ik het verschil nauwelijks zie

Ik plaats hier liever de volledige hernieuwde code, dat zal makkelijker zijn dan jou de aanpassingen uiteen te zetten.

Tegelijk heb ik nog een andere aanpassing gedaan voor het kolommen sorteren.

ook de frames tov elkaar gesorteerd op hun volgnummer (dus laatste karakter (cijfer))

Dat is wat ik eerst letterlijk had gedaan, maar zal maar correct werken zolang je niet hoger gaat dan frame 10, dus voor het geval dat één regel gewijzigd waardoor bv. 10 netjes na 9 zal komen.
Sub getnamen()
Dim frm As Object, pagina As Object, ctrl As Object, crij As Long, fkol As Long, pkol As Long
Application.ScreenUpdating = False
  With Sheets("ctrl-namen")
    .Cells.UnMerge
    .Cells.ClearContents
    .Cells.Borders.LineStyle = xlNone
    .Cells(1, 1) = "Multipage1"
    pkol = 1
    fkol = 0
    For Each pagina In UserForm1.MultiPage1.Pages
      pkol = fkol + 1
      With .Columns(pkol).Borders(xlEdgeLeft)
        .Weight = xlMedium
        .Color = RGB(58, 56, 56)
      End With
      .Cells(2, pkol) = " " & pagina.Caption & " "
      For Each frm In pagina.Controls
        If TypeName(frm) = "Frame" Then
          fkol = fkol + 1
          With .Columns(fkol).Borders(xlEdgeLeft)
            If .Weight <> xlMedium Then
              .Weight = xlThin
              .Color = RGB(58, 56, 56)
            End If
          End With
          .Cells(3, fkol) = " " & frm.Name & " "
          .Cells(3, fkol).BorderAround , Weight:=xlMedium, Color:=RGB(58, 56, 56)
          crij = 3
          For Each ctrl In frm.Controls
            crij = crij + 1
            .Cells(crij, fkol) = " " & ctrl.Name & " "
          Next
          If crij > 4 Then
            .Range(.Cells(4, fkol), .Cells(crij, fkol)).Sort key1:=.Cells(4, fkol), Header:=xlNo
          End If
        End If
      Next
      .Range(.Cells(2, pkol), .Cells(2, fkol)).Merge
      'kolommen sorteren en opmaken
      kolommen = (fkol - pkol) + 1
      If kolommen > 1 Then
        rijen = .UsedRange.Rows.Count - 2
        ReDim sort_kol(1 To kolommen)
        For i = 1 To kolommen
          sort_kol(i) = Join(Application.Transpose(.Cells(3, pkol + i - 1).Resize(rijen)), "|")
        Next i
        For i = 1 To kolommen - 1
          For ii = i + 1 To kolommen
            If Val(Replace(sort_kol(ii), " Frame", "", , , vbTextCompare)) < Val(Replace(sort_kol(i), " Frame", "", , , vbTextCompare)) Then
              tmp = sort_kol(i)
              sort_kol(i) = sort_kol(ii)
              sort_kol(ii) = tmp
            End If
          Next ii
        Next i
        For i = 1 To kolommen
          arr = Split(sort_kol(i), "|")
          .Cells(3, pkol + i - 1).Resize(rijen) = Application.Transpose(arr)
          aantal = .Cells(Rows.Count, pkol + i - 1).End(xlUp).Row - 3
          If aantal > 0 Then
            With .Cells(4, pkol + i - 1).Resize(aantal).Borders(xlEdgeBottom)
              .Weight = xlHairline
              .Color = RGB(58, 56, 56)
            End With
            With .Cells(4, pkol + i - 1).Resize(aantal).Borders(xlInsideHorizontal)
              .Weight = xlHairline
              .Color = RGB(58, 56, 56)
            End With
          End If
        Next i
      End If
    Next
    With .Columns(fkol + 1).Borders(xlEdgeLeft)
      .Weight = xlMedium
      .Color = RGB(58, 56, 56)
    End With
    .Range(.Cells(1, 1), .Cells(1, fkol)).Merge
    .Range(.Cells(1, 1), .Cells(1, fkol)).BorderAround , Weight:=xlMedium, Color:=RGB(58, 56, 56)
    .UsedRange.EntireColumn.AutoFit
  End With
End Sub

Groetjes,
Molly