Hallo Walter,

daar kan je een eenvoudige ALS formule voor gebruiken:

=ALS(A1=B1;A1;"")   in C1 typen, en deze formule doortrekken tot C300

SoftAid        

Walterh, als je deze 'vergelijkingsactie' slechts 1x moet doen is de oplossing van Erik natuurlijk (zoals gewoonlijk) hartstikke goed. Ik blijf ook bij het standpunt dat je eerst dingen met Excel's eigen functies moet oplossen voordat je de VBA induikt.

Maar toch.... Ik heb op mijn werk regelmatig deze actie nodig en heb daar ooit een klein stukje code voor geschreven die ik mijn 'Personal.xls' heb geplaatst. Zo is deze code heel snel oproepbaar. Sub VergelijkKolommen()
Dim iLaatsteCel As Integer, i As Integer
Dim c As Range
On Error Resume Next
   
    Range("C2:C65536").ClearContents
   
    i = 2
    iLaatsteCel = Range("B1").End(xlDown).Row

    For Each c In Range("B2:B" & iLaatsteCel)
        If Not (IsError(Application.WorksheetFunction.Match(c, Range("A:A"), 0))) Then
            If Err.Number = 1004 Then
                Err.Number = 0
                GoTo hier
            End If
            c.Copy Destination:=Cells(i, 3)
            i = i + 1
hier:
        End If
    Next c

End Sub
De werkwijze is heel simpel. Je plaatst in kolom A de tabel waarin je wilt gaan zoeken, In kolom B zet je de waarden waarmee je wilt gaan zoeken. En als je dan de code start, zal kolom C gevuld worden met de gelijke waarden uit B en A....

Als voorbeeld (bijlage) heb ik nog ff een worksheet gevuld met wat waarden als voorbeeld. Hierin zit nu ff een button waarmee je de code start. Als je 'm in je personal.xls zet, moet je 'm natuurlijk aanroepen via Extra, Macro, Marcros... (of je zet er een snelkoppeling bij)

Groet, Leo

Leo,

Als je dit proces gaat automatiseren is het beter om de "loop" te vermijden.

Je code doet dit:
staat 1ste cel in de andere kolom?
ja: schrijf naar werkblad
staat 2de cel in andere kolom?
....

Het zal vlugger gaan als je de manuele procedure - zoals ik beschreef: met formule en filter - automatiseert. Het verschil is waarschijnlijk al zichtbaar vanaf 1000 cellen.

Andere manier:
Zet beide kolommen in een matrix (in het geheugen). "Loop" doorheen de kleinste matrix met Match, zoals jij deed. Maak een derde matrix aan met de overeenkomende items. Wanneer alles vergeleken is, schrijf je de 3de matrix in 1 keer naar het werkblad.

fijn weekend!
Erik

Deze code is een automatisering van bovenstaande handelingen, met autofilter.
Option Explicit

Sub list_matches()
'Erik Van Geit
'070708

'compare columns A & B and list matches in column C
'Row 1 = headers

'EXAMPLE
'  A       B      C
'1 LIST 1  LIST 2 MATCHES
'2 Item 4  Item 4 Item 4
'3 Item 3  Item 5 Item 1
'4 Item 1  Item 2 Item 9
'5 Item 6  Item 1 Item 8
'6 Item 7  Item 9
'7 Item 8  Item 8
'8 Item 10
'9 Item 9

Dim LR As Long
Dim AFM As Boolean

Application.ScreenUpdating = False
AFM = ActiveSheet.AutoFilterMode
ActiveSheet.AutoFilterMode = False

    If Application.WorksheetFunction.CountA(Range("C1:D" & Rows.Count)) Then
    If MsgBox("The data in columns C & D will be erased. Continue?", 36, "WARNING") = vbNo Then Exit Sub
    End If

    With Range("A1:B" & Rows.Count)
    LR = .Find("*", .Cells(1, 1), xlFormulas, xlPart, xlByRows, xlPrevious, False, False).Row
    End With

    With Range("C2:C" & LR)
    .Formula = "=IF(COUNTIF(R2C1:R" & LR & "C1,RC[-1]),1,0)"
    .Value = .Value
    .Offset(-1, 0).AutoFilter Field:=.Cells(1, 1), Criteria1:="1"
    .Offset(0, -1).Copy
    .Offset(0, 1).Resize(1, 1).PasteSpecial xlPasteValues
    .EntireColumn.delete
    End With

    Range("C1") = "MATCHES"

Application.ScreenUpdating = True

End Sub
Als ik nog eens tijd heb, maak ik wat met matrices.

fijne zondag verder!
Erik

Walterh, zijn de 'schrijfwijzes' van beide kolommen wel gelijk? Kan je een voorbeeld plaatsen in een bijlage met wat namen?
Bij mij doet tie het wel gewoon....

Groet, Leo

Walterh, zoals ik al vroeg

zijn de 'schrijfwijzes' van beide kolommen wel gelijk?

Het antwoord daarop is: NEE. 
Welliswaar niet direct bij de 1e blik zichtbaar, maar toch... In kolom A heb je achter iedere naam een onzettende hoeveelheid spaties staan.
_{(Bekijk dit maar 'ns door op cel A2 te gaan staan en vervolgens in je formulebalk je cursor ergens achter de tekst te plaatsten. Je zal zien dat dit dan gewoon lukt... En dat kan alléén als er spaties staan!)}

Dit leidt in vergelijkingen altijd tot problemen. Een spatie wordt namelijk óók als leesteken meegenomen. En ja, dan heb je inderdaad nooit een gelijkenis.
Als je dit codeblokje ff in je VBE zet en 'runt' dan lukt het wel...
Sub VerwijderSpaties()
Dim iLaatsteCel As Integer
Dim c As Range

    iLaatsteCel = Range("A1").End(xlDown).Row

    For Each c In Range("A2:A" & iLaatsteCel)
        c = Trim(c)
    Next c

     MsgBox "Klaar..."

End Sub
...krijg je als resultaat de volgende namen:
lijst3
Sneeuwgans
Roodhalsgans
Ralreiger
Schreeuwarend
Dwerggors

Ik heb trouwens nooit geweten dat er zoveel vogelsoorten zijn zeg!

Groet, Leo

p.s. voor het gemak ook nog maar ff het complete bestand (mét spaties) en de extra code....

EDIT: Ttoegevoegd: de MsgBox aan het codeblokje...

Walterh, je kan de functie 'Trim' (weet ff de nederlandse benaming niet) ook in je worksheet zelf als formule inzettten.
Maak een lege kolom aan naast A. Zet in cel B2 de formule =TRIM(A2) en trek deze door naar het einde van je lijst. Kopieer kolom B en plak deze op dezelfde plaats terug als tekst (plakken speciaal). Ook dan zijn je spaties verdwenen.

Groet, Leo