Goed gezien Barthold.

Dit geeft zonder matrixformules:

in A3: =SOMPRODUCT((REST(KOLOM($D3:$GA3)-5;3)=0)*($D3:$GA3=15))
in B3: =SOMPRODUCT((REST(KOLOM($D3:$GA3)-5;3)=0)*($D3:$GA3))-SOMPRODUCT((REST(KOLOM($D3:$GA3)-5;3)=1)*($D3:$GA3))
in C3: =SOMPRODUCT((REST(KOLOM($D3:$GA3)-5;3)=0)*($D3:$GA3))

Dat is zeker niet te veel gevraagd spyder. Graag gedaan zelfs!  

De functie somproduct leunt dicht aan bij een matrixformule, vandaar dat de oplossing van het probleem ook geformuleerd kan worden met behulp van de sumproduct functie. De sumproductie bekijkt in essentie 2 matrices, en gaat door de matrices op de volgende wijze: van beide element 1, dan van beide element 2, dan van beide element 3, ..., tot alle elementen bekeken zijn. Wat doet de somproduct functie nu?

EERST: PRODUCTEN NEMEN
Het vermenigvuldigt element 1 van de eerste matrix met element 1 van de tweede matrix, dan vermenigvuldigt het element 2 van de eerste matrix met element 2 van de tweede matrix, dan vermenigvuldigt het element 3 van de eerste matrix met element 3 van de tweede matrix, enz.

VERVOLGENS: SOM NEMEN
Van alle producten wordt de som genomen.

Door nu de twee matrices slim te kiezen kunnen we bereiken wat we willen. Namelijk:
matrix 1 is een matrix met nullen en enen; matrix 2 zijn alle getallen zelf.

Zo vatten we matrix 1 op:
neem een 1 als het een oranje kolom is, een 0 als het geen oranje kolom is. Oranje kolommen komen vanaf kolom E om de 3 kolommen voor. Een functie die kan zien of een cel zich in een oranje kolom bevindt, is:

REST(KOLOM($D3:$GA3)-5;3)=0

Ma.w. Excel gaat na of de kolomnummer een veelvoud is van 3 (de rest is 0)?
Als dit zo is, krijgt het de waarde 1, is dit niet zo krijgt het de waarde 0.

Samengevat, wat we dus krijgen is een som: getallen in een oranje kolom krijgen coëfficiënt 1, getallen in de andere kolommen krijgen coëfficiënt 0 en tellen dus niet mee.

Hopelijk is dit duidelijk genoeg. Meer dan dit zit er niet achter...

WG

Ik heb er maar één woord voor : KLASSE !!!!

Alles werkt en zonder matrixes en macro's.
Ik heb wel enige tijd besteed aan het uitdokteren hoe de formle eigenlijk in elkaar zit daar het testbestandje niet overeenkomt met het orginele bestand.
Door het te proberen en uw uitleg kwam ik er uit.

Nogmaals bedankt.

Just_a_Guy.