*extra vraagje*

Omdat ik héél veel subs heb met vaak héél veel code en dus ook enorm veel variabelen gebruik ben ik nu eerst van plan om eens een deftige ‘opkuis’ te doen inzake die variabelen.
Is er in de VB-Editor ergens een optie om een opsomming te krijgen van alle gebruikte variabelen met eventueel de naam van de sub waarin ze gebruikt worden?

Mijn doel is om snel (via zulks overzicht) te kunnen bepalen enerzijds welke variabelen ik meermaals gebruik met hetzelfde doel zodat ik deze éénmalig kan definiëren via public en zodoende dus plaatsbesparend kan werken in de subs zelf en anderzijds om een meer ‘logische’ benaming voor de variabelen te kunnen creëren binnen het gehele project.

Ik zou zo onder andere (indien dit geen conflicten zou creëren tenminste) bevoorbeeld ook al mijn gebruikte werkbladen (die ik sowieso in meerdere subs gebruik) via het “workbook_open”-event willen laten definiëren via het ‘set’-statement waarvan ik de variabelen ‘public’ zet zodat ik dat ook niet meer in elke sub afzonderlijk moet gaan doen.

Groetjes,
Bieke

Hey Bieke,

opnieuw op te bouwen met de arraylist-methode heb ik eindelijk, 24u later, een werkend eindresultaat bereikt

Oeps, aangezien je niet op mijn bericht had gereageerd dacht ik dat je het ofwel meteen had gefikst ofwel met gans andere dingen bezig was.

Ik zag in je code dat je ook hier je werkblad als tussenstap gebruikt, dus ik heb nu toch maar vlug een alternatiefje gemaakt:
Sub uniekejaren()

Dim bl As Long, i As Long, j As Variant, ws As String, wsStats As Worksheet
Set wsStats = Sheets("stats-jr-par")
With CreateObject("System.Collections.Arraylist")
  For bl = 1 To 3
    ws = Choose(bl, "IDX_G_PR", "IDX_H_PR", "IDX_O_PR")
    j = Application.Transpose(Sheets(ws).Range("D2:D" & Sheets(ws).Cells(Rows.Count, 4).End(xlUp).Row))
    For i = 1 To UBound(j)
      If Not .contains(j(i)) Then .Add j(i)
    Next
  Next bl
  .Sort
  j = Application.Transpose(.toarray)
  wsStats.Rows("3:1000").ClearContents
  wsStats.Cells(3, 1).Resize(.Count) = j
End With

End Sub
En, terwijl ik toch nog eens bezig was, ook als reactie op je "extra vraag", uit te voeren op een nieuw werkblad:
Sub variabelen()
   
For Each c In ThisWorkbook.VBProject.VBComponents
  Set m = c.CodeModule
  For i = 1 To m.CountOfLines
    If InStr(m.Lines(i, 1), "Sub") Or InStr(m.Lines(i, 1), "Function") Then
      p = m.Lines(i, 1)
    End If
    If Left(Trim(m.Lines(i, 1)), 3) = "Dim" Then
      s = Split(m.Lines(i, 1), ",")
      For t = LBound(s) To UBound(s)
        r = r + 1
        Cells(r, 1) = c.Name
        Cells(r, 2) = Trim(p)
        Cells(r, 3) = Trim(s(t))
      Next t
    End If
  Next i
Next c

End Sub
Voorwaarde hierbij is wel (maar dat is zo in je project) dat alle variabelen gedeclareerd zijn.

Groetjes,
Molly

Hey Bieke,

dan had ik nog wekenlang pogingen mogen doen, ze zouden altijd zonder succes geweest zijn want  het "choose()" element ben ik nog nooit tegen gekomen

Weet ik nog zo niet, hoor . "Choose" was in dit geval een leuke keuze, maar met iets array-achtig was daar ook wel uit te komen.

(Tussen haakjes:
zoals je zelf zei, zeker niet meer actueel, maar een array vullen en 'public' beschikbaar houden lukt wel degelijk, alleen even kijken wat je waar zet )

Groetjes,
Molly

Hey Bieke,

Oei, en vermits ik meer dan waarschijnlijk slechts over een deel van je bestand beschik heeft jou het resultaat sturen (gaat hier namelijk prima) ook geen zin, dus vrees ik dat je op zoek moet naar één of andere instelling...
Succes!
En mocht het hoegenaamd niet lukken, dan bekijken we wel hoe het verder kan (het hier voor jou doen is altijd een mogelijkheid, de vraag zal alleen zijn of je alles kan delen).
Vandaag ben ik er niet meer, dus ik hoor het later wel

Groetjes,
Molly

goedenavond allemaal,

Desondanks de stilte de afgelopen drie dagen ben ik intensief bezig geweest met mijn vba-projectje.
Zo heb ik na een fikse brainstorm-sessie mijn volledige aanpak aanzienlijk gewijzigd.
Grootste wijziging is dat ik de 6 “IDX”-werkbladen samengevoegd heb tot 1 werkblad waarbij ik de zichtbare kolommen via code manipuleer volgens het soort register dat ik ga indexeren.
Momenteel ben ik dus bezig met alle code die reeds af was in de vorige versie aan het heropbouwen voor de nieuwe versie.
Tot nu toe ging dit zeer vlot maar nu ben ik toch wel op een klein hindernisje gebotst.
Namelijk het tellen van de akten voor de 2 soorten statistieken.
Het eerste deel heb ik al tot een goed einde gebracht, namelijk de unieke jaren enerzijds en unieke namen anderzijds in de juiste kolom van elk “stats”-werkblad plaatsen.
Het is echter het tweede deel, de telling, waar ik een beetje kom vast te zitten in de opbouwstructuur gezien er hier nu met drie criteria geteld moet worden.

In bijlage de allernieuwste versie (1.0) van mijn (licht hernoemde) bestand.
De code voor de stats zit achter de werkbladen “jaarstats” en “naamstats”.


Groetjes,
Bieke

*edit*
in de sub achter werkblad "naamstats" staat in de commentaar "kolom A" vermeld, hier moet dit echter "kolom B" zijn.

Hey Bieke,

heb het gevonden   

Zo zie je maar weer dat het ook in orde komt als ik nog eens op (mini)citytrip ga

Mij er alsnog even over buigen is dus enkel omdat je meermaals de snelheid als belangrijk criterium hebt vermeld.
Welnu, traag (een héél rekbaar begrip) is je code zeker niet, maar iets zei me dat er nog winst moest te boeken zijn.
Daarom heb ik nog eens een testje gedaan met 2000 rijen, er daarbij voor zorgend dat er 500 verschillende jaartallen in voorkwamen.
Dan doet jouw code dat in 26 seconden, wat dus enkel relevant zou zijn als je die code heel dikwijls uitvoert

Maar met onderstaande (iets meer lijntjes wel) waarbij ik elke rij één voor één bij het juiste element laat optellen (CountIfs zal je dus niet meer aantreffen, en ik weet het wel, dat 'klinkt' op het eerste zicht misschien als zinloos probeersel, vooral voor wie er nog minder in thuis is) kom ik op 0,08 seconden.

Sub statsjrpar()
 
Dim idx_type As Integer
Dim j As Long, stat_jaren As Long, i As Long, hor As Long, vert As Long
Dim arjaar, arr_jaren, parochies, gegevens
With Sheets("idx")
  arjaar = .Range("H3:H" & .Cells(Rows.Count, 8).End(xlUp).Row)
  With CreateObject("System.Collections.Arraylist")
    For j = 1 To UBound(arjaar)
      If Not .contains(arjaar(j, 1)) Then .Add arjaar(j, 1)
    Next j
    .Sort
    Cells(3, 1).Resize(.Count).Value = Application.Transpose(.toarray)
  End With
  Range("B3:S" & Cells(Rows.Count, 1).End(xlUp).Row).ClearContents
  parochies = Array(Cells(1, 2).Value, Cells(1, 5).Value, Cells(1, 8).Value, Cells(1, 11).Value, Cells(1, 14).Value)
  stat_jaren = Cells(Rows.Count, 1).End(xlUp).Row - 2
  arr_jaren = Application.Transpose(Cells(3, 1).Resize(stat_jaren))
  ReDim resultaat(1 To stat_jaren, 1 To 18) As Long
  With Sheets("idx")
    gegevens = .Range("B3:L" & .Cells(Rows.Count, 1).End(xlUp).Row)
    For i = 1 To UBound(gegevens)
      idx_type = Application.Match(Left(gegevens(i, 1), 1), Array("G", "H", "O"))
      hor = (Application.Match(gegevens(i, 11), parochies, 0) * 3) + idx_type - 3
      vert = Application.Match(gegevens(i, 7), arr_jaren, 0)
      resultaat(vert, hor) = resultaat(vert, hor) + 1
      resultaat(vert, 15 + idx_type) = resultaat(vert, 15 + idx_type) + 1
    Next i
  End With
  Cells(3, 2).Resize(stat_jaren, 18) = resultaat
End With

End Sub

Groetjes,
Molly

***update***

heb eindelijk de 'fout' in de code gevonden 

nl in dit lijntje code :
gegevens = .Range("B3:L" & .Cells(Rows.Count, 1).End(xlUp).Row)

dit moet eigenlijk het volgende zijn :
gegevens = .Range("B3:L" & .Cells(Rows.Count, 2).End(xlUp).Row)

de foutmelding kwam doordat de laatste rij in de gegevens leeg was bij een rows.count op de 1e kolom 


groetjes,
Bieke