Hallo,

Er wordt voor het werk een spreadsheet bijgehouden met de fouten die gemaakt worden per persoon.
Dit is een file die er ongeveer zo uitziet :

werkblad 1  - kolom met :
datum ; naam van de persoon ; soort fout ... (de rest is van minder belang)

werkblad 2 - kolom met
naam  van de persoon (idem als op werkblad 1) ; dan de 12 maanden.

Bedoeling is dat er daar bijgehouden wordt hoeveel fouten elke persoon op een maand gemaakt heeft. (dus dit is gewoon een cijfer)

Hoe kan dat automatisch ingevuld worden, dus als er op werkblad 1 een rij ingevuld word (datum, naam, type fout ...), dat er dan op werkblad 2 in de juiste maand eentje bijgeteld wordt in het foutentotaal voor die persoon.

Dus als vb. Jantje op 10 aug. een fout maakt, zou er op werkblad 2 voor Jantje in de maand augustus 1 fout moeten komen, of bijgeteld worden bij het getal dat er al stond.

Hallo,

De rare output van Table-It trok mijn aandacht. Leo, hoe je er in geslaagd bent om dit resultaat te krijgen is me een raadsel. Ik heb het even uitgetest in de Table-It topic zonder problemen.

Met de functie somproduct kunnen we in bepaalde gevallen kiezen tussen het maalteken of de "dubbelmin" (--) , maar ze moeten niet allebei gebruikt worden. In mijn voorbeeld (een kleine uitbreiding van Leos bijlage) zijn de minnetjes er uit.

DATABASE met alle fouten
  A        B    C                 
1 datum    naam soort fout         
2 5/02/07  jan  lag te slapen     
3 7/02/07  piet fout advies       
4 18/03/07 jan  gaf teveel korting
5 19/03/07 piet lag te slapen     
6 20/03/07 jan  fout advies       
7 21/03/07 jan  gaf teveel korting

Error input
[Table-It] version 07 by Erik Van Geit

OVERZICHT met de formules
  A            B  C  D  E  F  G  H  I  J  K  L  M  N     
1 naam / maand 1  2  3  4  5  6  7  8  9  10 11 12 TOTAAL
2 jan          0  1  3  0  0  0  0  0  0  0  0  0  4     
3 piet         0  1  1  0  0  0  0  0  0  0  0  0  2     

Jaaroverzicht
[Table-It] version 07 by Erik Van Geit
RANGE FORMULA (1st cell)
B2:M3 =SUMPRODUCT(('Error input'!$B$2:$B$1000=Jaaroverzicht!$A2)*(MONTH('Error input'!$A$2:$A$1000)=Jaaroverzicht!B$1))
N2:N3 =SUM(B2:M2)

[Table-It] version 07 by Erik Van Geit
ADRES FORMULE (1ste cel)
B2:M3 =SOMPRODUCT(('Error input'!$B$2:$B$1000=Jaaroverzicht!$A2)*(MAAND('Error input'!$A$2:$A$1000)=Jaaroverzicht!B$1))
N2:N3 =SOM(B2:M2)

[Table-It] version 07 by Erik Van Geit
beste groeten,
Erik

de "booleans" (waar onwaar) moeten omgezet worden naar 1 of 0
dat kan op verschillende manieren: naargelang het geval kan je kiezen.

klein voorbeeld
=WAAR*WAAR
resultaat 1

in de somproductformule kan je dus meestal kiezen
1. de dubbelmin
=SOMPRODUCT(--(bereik1=cell1);--(bereik2=cell2))
2. of het product
=SOMPRODUCT((bereik1=cell1)*(bereik2=cell2))

de werking is min of meer hetzelfde, maar in een andere rekenvolgorde
1. er worden twee matrices aangemaakt met "WAAR-ONWAAR", die beide afzonderlijk worden omgezet naar "1-0"matrices
dan wordt daarvan somproduct berekend
2. er worden twee matrices aangemaakt met "WAAR-ONWAAR", die met elkaar worden vermenigvuldigd, wat 1 enkele "1-0"matrix oplevert
dan wordt daarvan somproduct berekend: hier is "product" enigszins overbodig, want er is slechts 1 matrix: enkel "som" moet nog berekend worden
je kan voorbeeld 2 dus ook vervangen door een matrixformule
{=SOM((bereik1=cell1)*(bereik2=cell2))}
(invoeren zonder {}, dan "bevestigen" met Control+Shift+Enter)

Voorbeeld 1. met de dubbelminnen geniet mijn voorkeur, omdat daaruit de "aangeboren natuur" van somproduct het meeste naar voren komt

Dit was erg in de rapte geschreven: hopelijk is alles OK

goeienacht,
Erik