*

Help!

PC-Problemen?
De vrijwilligers van Oplossing.be zoeken gratis met u mee!

Hulp bij posten

Recente topics

Pagina's: [1]   Omlaag

Auteur Topic: spaties in excel als scheidingsteken gebruiken  (gelezen 7671 keer)

0 leden en 1 gast bekijken dit topic.

Offline ErnieMHC

  • Lid
  • *
  • Berichten: 31
  • Geslacht: Man
  • Oplossing.be
spaties in excel als scheidingsteken gebruiken
« Gepost op: 17 juni 2007, 21:15:34 »
wie kan mij helpen.
Ik heb een 3500 tal regels waarin achternaam initialen meisjesnaam in 1 cel staan.
bijv: "Jansen L.P.H. Prins"  Dit staat in 1 cel Nu wil ik graag die "Prins" in een andere cel plaatsen. Uiteindelijk wil ik nl die 3500 namen op alfabetische volgorde hebben waarbij bij de gehuwden de meisjesnaam (Prins dus) criterium moet zijn. Dus Jansen L.P.H. Prins moet bij de sortering onder de P komen.

k ben heel benieuwd op een reactie!

groeten
Gelogd
Acer 9300 Aspire
Standaard emailprogramma: Outlook Express2007
Standaard Operating System: Windows Vista Standaard Browser:Internet Explorer 7
Office pro 2007

Offline RedHead

  • Excel-Expert
  • Ambassadeur
  • *****
  • Berichten: 2.284
  • Geslacht: Man
  • Met Excel lukt 't wel.... (toch???)
Re: spaties in excel als scheidingsteken gebruiken
« Reactie #1 Gepost op: 17 juni 2007, 22:04:01 »
ErnieMHC, Als die 'meisjesnamen' altijd uit een 'enkele' naam bestaan kan je hiermee verder...
  A                   B     
1 Jansen L.P.H. Prins Prins 

Sheet1
[Table-It] version 06+ by Erik Van Geit
Code: [Selecteer]
RANGE FORMULA (1st cell)
B1    =RIGHT(A1;LEN(A1)-FIND("~";SUBSTITUTE(A1;" ";"~";LEN(A1)-LEN(SUBSTITUTE(A1;" ";"")))))

[Table-It] version 06+ by Erik Van Geit
Of de formule in het nederlands...
Code: [Selecteer]
=RECHTS(A1;LENGTE(A1)-VIND.ALLES("~";SUBSTITUEREN(A1;" ";"~";LENGTE(A1)-LENGTE(SUBSTITUEREN(A1;" ";"")))))
Groet, Leo
Gelogd
______________________________

Groet, Leo

Offline Erik Van Geit

  • Excel-Expert
  • Ervaren lid
  • *****
  • Berichten: 306
  • Geslacht: Man
Re: spaties in excel als scheidingsteken gebruiken
« Reactie #2 Gepost op: 18 juni 2007, 00:28:10 »
Hallo,

Leo, even oppassen, de forumsoftware interpreteert sommige combinaties "verkeerd".
NB: Dat heeft niets met Table-It te maken.
Code: [Selecteer]
=RECHTS(A1;LENGTE(A1)-VIND.ALLES("~";SUBSTITUEREN(A1;" ";"~";LENGTE(A1)-LENGTE(SUBSTITUEREN(A1;" ";"")))))De truuk is om een extra spatie na de ; in te voegen.
Code: [Selecteer]
=RECHTS(A1;LENGTE(A1)-VIND.ALLES("~";SUBSTITUEREN(A1; " ";"~";LENGTE(A1)-LENGTE(SUBSTITUEREN(A1;" ";"")))))
Dat zijn 7 functies.

Het kan ook met 6 functies:
Code: [Selecteer]
=RECHTS(A1;LENGTE(A1)-VIND.ALLES("~";SUBSTITUEREN(A1; " ";"~";LENGTE(A1)-LENGTE(SUBSTITUEREN(A1;" ";"")))))
Als je veel van dit soort formules nodig hebt, en je vindt het wat traag werken, is een door de bebruiker gedefineerde functie wellicht nuttig. Ik denk dat die nog sneller zal lopen. We kunnen dan immers gebruik maken van StrReverse om in 1 klap de laatste spatie te vinden.

ErnieMHC , er is toch wel een groot vraagteken bij dit probleem. Wie zegt dat de familienaam altijd in 1 woord is?

beste groeten,
Erik
Gelogd

Offline ErnieMHC

  • Lid
  • *
  • Berichten: 31
  • Geslacht: Man
  • Oplossing.be
Re: spaties in excel als scheidingsteken gebruiken
« Reactie #3 Gepost op: 18 juni 2007, 08:49:14 »
Beste Erik, dat klopt dat is niet altijd zo. Het zou in mijn voorbeeld bijvoorbeeld
"Jansen L.P.H. Prins de"kunnen zijn. Hierbij staat de altijd achteraan. Dus het gaat eigenlijk om de naam na de tweede spatie.

Uiteindelijk ben ik al volledig geholpen met de oplossing. Soms staat er ook nog eens een "-" voor de meisjesnaam. Je hoort al. De database is slecht gevuld!. Ik heb de spatie nu veranderd in - teken. En ik kan prima sorteren. Alweer bedankt.
Rest mij nog een vraagje. Wat betekent "~" ? Die kan ik niet plaatsen wat dit doet.

groeten
Ernie
Gelogd
Acer 9300 Aspire
Standaard emailprogramma: Outlook Express2007
Standaard Operating System: Windows Vista Standaard Browser:Internet Explorer 7
Office pro 2007

Offline RedHead

  • Excel-Expert
  • Ambassadeur
  • *****
  • Berichten: 2.284
  • Geslacht: Man
  • Met Excel lukt 't wel.... (toch???)
Re: spaties in excel als scheidingsteken gebruiken
« Reactie #4 Gepost op: 18 juni 2007, 10:32:05 »
ErnieMHC, Zoals ik al zei...
Citaat van: Leo
die 'meisjesnamen' altijd uit een 'enkele' naam bestaan
Maar je geeft nu aan dat
Citaat van: ErnieMHC
"Jansen L.P.H. Prins de"
ook mogelijk is...

Je regel
Citaat
Dus het gaat eigenlijk om de naam na de tweede spatie.
roept nog meer vragen op. Wat te doen met een naam met 2 tussenvoegsels? Dus 1 van de man en 1 van de vrouw? (vb: "van Jansen L.P.H. Prins de". Dan moet het ineens de 3e spatie worden. En deze dan... "van der Jansen L.P.H. Prins de"?

Dat wordt dan echt programmeren lijkt mij. Ik zit te denken aan het verwijderen van al die tussenvoegsels (die in een tabel worden bijgehouden) om zo de 'schone' meisjesnaam te kunnen vinden.

Groet, Leo

EDIT:
Citaat van: Erik
Leo, even oppassen, de forumsoftware interpreteert sommige combinaties "verkeerd".
NB: Dat heeft niets met Table-It te maken.
Erik, bedankt voor de tip. Ik had het nog niet gezien.
Citaat van: Erik
Het kan ook met 6 functies
Ehhh..., ik tel er bij jou óók 7...  ???
Gelogd
______________________________

Groet, Leo

Offline ErnieMHC

  • Lid
  • *
  • Berichten: 31
  • Geslacht: Man
  • Oplossing.be
Re: spaties in excel als scheidingsteken gebruiken
« Reactie #5 Gepost op: 18 juni 2007, 10:43:40 »
Dag leo,
Ja je hebt gelijk, maar bij nader inzien staat er dus aan "-" voor de meisjesnaam. ??? Ik heb dus in jouw formule de spatie veranderd in "-" en krijg de meisjesnaam.  ;)De database is wat dat betreft het probleem. Het is niet consequent gevuld.

groeten.
Gelogd
Acer 9300 Aspire
Standaard emailprogramma: Outlook Express2007
Standaard Operating System: Windows Vista Standaard Browser:Internet Explorer 7
Office pro 2007

Offline RedHead

  • Excel-Expert
  • Ambassadeur
  • *****
  • Berichten: 2.284
  • Geslacht: Man
  • Met Excel lukt 't wel.... (toch???)
Re: spaties in excel als scheidingsteken gebruiken
« Reactie #6 Gepost op: 18 juni 2007, 11:13:14 »
ErnieMHC, Ik moet zeggen, da's een goed bericht... Dat er gebruik gemaakt wordt van het 'min-teken' vóór de meisjesnaam. Dat maakt het zoeken inderdaad een stuk makkelijker! ;D

Topic opgelost?

Groet, Leo
Gelogd
______________________________

Groet, Leo

Offline Erik Van Geit

  • Excel-Expert
  • Ervaren lid
  • *****
  • Berichten: 306
  • Geslacht: Man
Re: spaties in excel als scheidingsteken gebruiken
« Reactie #7 Gepost op: 18 juni 2007, 13:06:49 »
Hallo,

In verband met die 6 functies: sorry, even verstrooid geweest.

De formule die ik wilde posten was:
Code: [Selecteer]
=VERVANGEN(A1;1;VIND.ALLES("|";SUBSTITUEREN(A1; " ";"|";LENGTE(A1)-LENGTE(SUBSTITUEREN(A1; " ";""))));"")
beste groeten,
Erik
Gelogd

Offline ErnieMHC

  • Lid
  • *
  • Berichten: 31
  • Geslacht: Man
  • Oplossing.be
Re: spaties in excel als scheidingsteken gebruiken
« Reactie #8 Gepost op: 18 juni 2007, 13:08:47 »
Ja, bijna,  ;)
Ik kan de formule nog niet helemaal vertalen. Wat doet "~"?
Gelogd
Acer 9300 Aspire
Standaard emailprogramma: Outlook Express2007
Standaard Operating System: Windows Vista Standaard Browser:Internet Explorer 7
Office pro 2007

Offline Erik Van Geit

  • Excel-Expert
  • Ervaren lid
  • *****
  • Berichten: 306
  • Geslacht: Man
Re: spaties in excel als scheidingsteken gebruiken
« Reactie #9 Gepost op: 18 juni 2007, 13:10:18 »
Citaat van: ErnieMHC op 18 juni 2007, 10:43:40
Dag leo,
Ja je hebt gelijk, maar bij nader inzien staat er dus aan "-" voor de meisjesnaam. ??? Ik heb dus in jouw formule de spatie veranderd in "-" en krijg de meisjesnaam.  ;)De database is wat dat betreft het probleem. Het is niet consequent gevuld.

groeten.
Als er steeds een "-" voor de meisjesnaam staat, heb je genoeg aan een formule als deze:
=DEEL(A1;VIND.ALLES("-";A1)+1;999)
Gelogd

Offline RedHead

  • Excel-Expert
  • Ambassadeur
  • *****
  • Berichten: 2.284
  • Geslacht: Man
  • Met Excel lukt 't wel.... (toch???)
Re: spaties in excel als scheidingsteken gebruiken
« Reactie #10 Gepost op: 18 juni 2007, 13:54:40 »
@Erik,
Citaat van: Erik
In verband met die 6 functies: sorry, even verstrooid geweest
Dat wordt je best vergeven als je ziet dat je om half één 's nachts nog voor de mensheid bezig bent... ;) ;D

@Erik, Scherp gevonden!
Code: [Selecteer]
=DEEL(A1;VIND.ALLES("-";A1)+1;999)Dat zal een stuk sneller lopen met een tabel van 3500 namen...

@ErnieMHC,
Citaat
Wat doet "~"?
Om een formule te ontcijferen (en dus te begrijpen) knip ik 'm altijd in 'stukjes' per functie. De tilde (~) wordt in de plaats gezet van de spaties in de text-string (de 1e 'SUBSTITUEREN'). In de 2e 'SUBSTITUEREN' vervang je alle spaties voor 'geen spaties'. Hiervan bepaal je de lengte van de string die je vervolgens aftrekt van de hele string inclusief spaties. Je ziet dan in jouw voorbeeld dat er dus 2 spaties in de string zitten. Deze gevonden '2' kan je dan weer gebruiken in de 1e 'SUBSTITUEREN' om aan te geven dat je de 2e spatie wilt vervangen voor een tilde.
Daarna ga je in (nog steeds in de formule!)-string zoeken naar de positie van die tilde met de functie vind.alles (hiermee weet je dan dus op welke plek in de string je kan gaan afbreken).
Je gebruikt in deze formule expres een teken dat niet gebruikt wordt in standaard woorden of zinnen. Je weet dan altijd dat je zoekt naar een uniek karakter... (je kan dus bijvoorbeeld ook een | of een ^ gebruiken)

Ik hoop dat het zo weer ietsje duidelijke is....  ;D

Groet, Leo
Gelogd
______________________________

Groet, Leo

Offline ErnieMHC

  • Lid
  • *
  • Berichten: 31
  • Geslacht: Man
  • Oplossing.be
Re: spaties in excel als scheidingsteken gebruiken
« Reactie #11 Gepost op: 18 juni 2007, 14:07:54 »
Leo en Erik,
heel erg bedankt. Het is zeker duidelijker en het werkt als een speer!

gegroet,
Ernie.
Gelogd
Acer 9300 Aspire
Standaard emailprogramma: Outlook Express2007
Standaard Operating System: Windows Vista Standaard Browser:Internet Explorer 7
Office pro 2007

Offline Erik Van Geit

  • Excel-Expert
  • Ervaren lid
  • *****
  • Berichten: 306
  • Geslacht: Man
Re: spaties in excel als scheidingsteken gebruiken
« Reactie #12 Gepost op: 18 juni 2007, 16:16:38 »
Graag gedaan :)

Enkele uren geleden had ik dit overzicht klaar, maar kon op het laatste nippertje niet verzenden.

  A                          B                         
1 één nogiets nogwat laatste éénnogietsnogwatlaatste   
2                            3                         
3                            één nogiets nogwat|laatste
4                            één nogiets nogwat|laatste
5                            19                         
6                            laatste                   

Blad1
[Table-It] version 07 by Erik Van Geit
Code: [Selecteer]
RANGE FORMULA
B1    =SUBSTITUTE(A1, " ","")
B2    =LEN(A1)-LEN(SUBSTITUTE(A1, " ",""))
B3    =SUBSTITUTE(A1, " ","|",B2)
B4    =SUBSTITUTE(A1, " ","|",LEN(A1)-LEN(SUBSTITUTE(A1, " ","")))
B5    =FIND("|",SUBSTITUTE(A1, " ","|",LEN(A1)-LEN(SUBSTITUTE(A1, " ",""))))
B6    =REPLACE(A1,1,FIND("|",SUBSTITUTE(A1, " ","|",LEN(A1)-LEN(SUBSTITUTE(A1, " ","")))),"")

[Table-It] version 07 by Erik Van Geit
Code: [Selecteer]
ADRES FORMULE
B1    =SUBSTITUEREN(A1; " ";"")
B2    =LENGTE(A1)-LENGTE(SUBSTITUEREN(A1; " ";""))
B3    =SUBSTITUEREN(A1; " ";"|";B2)
B4    =SUBSTITUEREN(A1; " ";"|";LENGTE(A1)-LENGTE(SUBSTITUEREN(A1; " ";"")))
B5    =VIND.ALLES("|";SUBSTITUEREN(A1; " ";"|";LENGTE(A1)-LENGTE(SUBSTITUEREN(A1; " ";""))))
B6    =VERVANGEN(A1;1;VIND.ALLES("|";SUBSTITUEREN(A1; " ";"|";LENGTE(A1)-LENGTE(SUBSTITUEREN(A1; " ";""))));"")

[Table-It] version 07 by Erik Van Geit
beste groeten,
Erik
Gelogd
Pagina's: [1]   Omhoog
 


www.combell.com