Auteur Topic: Testen op open rekenbladen. (gelezen 4024 keer)

spyder · « **Gepost op:** 18 november 2005, 23:34:08 »

Hoi,

Ik zit met een klein probleem.

Ik wil in mijn VBA code testen of een andere werkmap open staat of niet, dit om foutmeldingen te voorkomen.

Het zou dus ongeveer iets moeten zijn zoals (in "mensentaal"dan

) :
als de map Picklijst.xls niet open is, moet deze geopend worden.

groetjes

SoftAid · « **Reactie #1 Gepost op:** 18 november 2005, 23:58:46 »

Hallo Spyder,

zo te horen moet deze "picklijst.xls" zowieso open om het eerste xls goed te kunnen uitvoeren. Kan je dan niet beter in je VBA code ( op de juiste plaats) aangeven dat VBA dat bestand moet openen. Daar zijn toch eenvoudige commando's voor. Zoiets als Workbooks.Open filename:="picklijst.xls"

SoftAid

spyder · « **Reactie #2 Gepost op:** 19 november 2005, 12:19:37 »

Hoi SoftAid,

Het is inderdaad eerst de bedoeling om het bestand picklijst.xls te openen, maar bij het schrijven en testen van mijn code krijg ik geregeld de foutmelding dat het bestand Picklijst.xls open staat en hij daardoor in de onderbrekingsmodus gaat. Voor mij is dit geen probleem, ik sluit het gewoon terug af en start de code opnieuw, maar ik probeer het zo volledig mogelijk te maken omdat meerdere personen hiermee gaan werken, en het dus een beetje "fool proof" moet zijn. _{Ik probeer rekening te houden met ALLE mogelijke stommiteiten die zich kunnen voordoen}

Citaat

Daar zijn toch eenvoudige commando's voor. Zoiets als Workbooks.Open filename:="picklijst.xls"

Daar was ik van vertrokken, maar ik zou graag van te voren willen testen of het bestandje al dan niet open staat.

groetjes

SoftAid · « **Reactie #3 Gepost op:** 19 november 2005, 13:23:56 »

Citaat van: spyder op 19 november 2005, 12:19:37

...maar bij het schrijven en testen van mijn code krijg ik geregeld de foutmelding dat het bestand Picklijst.xls open staat en hij daardoor in de onderbrekingsmodus gaat.

Gebruik dan in het begin van de macro iets als: Workbooks.Close voor picklijst.xls , dan ben je zeker dat het bestand gesloten is als je de macro start.
Ik ben hier ook gene straffe in hoor...

succes,

SoftAid

LucHeyndrick · « **Reactie #4 Gepost op:** 19 november 2005, 15:44:36 »

Hallo,

Sub TestWorkbook()
Dim strWorkbook As String
Dim strWorkbookPath
Dim wWorkbook As Workbook
Dim myWorkbook As Workbook
strWorkbookPath = "C:\Documents and Settings\Standaard\Mijn documenten\Picklijst.xls"
strWorkbook = "Picklijst.xls"
For Each wWorkbook In Application.Workbooks
If wWorkbook.Name = strWorkbook Then
Set myWorkbook = Workbooks(strWorkbook)
End If
Next
If myWorkbook Is Nothing Then
MsgBox "Niet geopend"
Else
MsgBox "Workbook Open"
End If
End Sub

Luc

spyder · « **Reactie #5 Gepost op:** 19 november 2005, 16:23:43 »

Hoi SoftAid,

Citaat van: SoftAid op 19 november 2005, 13:23:56

Gebruik dan in het begin van de macro iets als: Workbooks.Close voor picklijst.xls ,

Ik heb dit niet getest, maar ik voel aan mijn theewater dat ik hier dan ok weer een foutmelding gekregen had omdat ie die workbook niet gevonden had.

Citaat

Ik ben hier ook gene straffe in hoor...

Ik ook niet, maar hier lopen enkele straffe gasten rond aan wie ge dat kunt vragen.

@ Luc,

Je functie werkt prima voor mij.

Ik had het liever geinterpreteerd in mijn code, maar door deze procedure nu op te roepen in mijn code werkt het ook prima.

Ge gaat me dus niet horen klagen.

Bedankt, en tot de volgende vraag.

_{('t is nog lang niet af )}

barthold · « **Reactie #6 Gepost op:** 19 november 2005, 16:32:14 »

Zo kan het ook:
Function IsBookOpen(ByVal TargetBook As String) As Boolean
On Error Resume Next
IsBookOpen = CBool(Len(Application.Workbooks(TargetBook).Name) > 0)
End Function

Aanroepen in andere code doe je zo:
msgbox IsBookOpen("picklist.xls")

Voordelen van deze methode:
> Sneller, want er is geen test nodig van alle objecten in de workbooks collectie.
> Minder code, geen variabele-declaraties
> Laat ook toe op addins te testen, bv. IsBookOpen("funcres.xla"), funcres.xla is een MS-addin. Dit kan niet met de andere methode, omdat addins niet als object in de workbooks collectie bestaan...

Groeten,
Bart

LucHeyndrick · « **Reactie #7 Gepost op:** 19 november 2005, 16:34:36 »

Nu je toch over een functie spreekt, kan je er misschien maar beter een echte functie van maken. Zo kan je deze code nog eenvoudiger oproepen, en dat voor verschillende bestanden op andere plaatsen in je bestand:

Function TestWorkbook(strWorkbook As String, strWorkbookPath As String)

Dim wWorkbook As Workbook
Dim myWorkbook As Workbook
For Each wWorkbook In Application.Workbooks
If wWorkbook.Name = strWorkbook Then
Set myWorkbook = Workbooks(strWorkbook)
End If
Next
If myWorkbook Is Nothing Then
Workbooks.Open strWorkbookPath
End If
End Function

En die code om eerst het bestand te sluiten... of het bestand te openen, is op te lossen door bovenaan gewoon:
On Error Resume Next
te zetten.

Maar ik gebruik dat liever niet indien fouten anders op te vangen zijn. Bijvoorbeeld door geen fouten te maken.
Die On Error geeft me een beetje het gevoel alsof ik een proefwerk afgeef met allerlei doorstrepingen, en verbeteringen er op... en dan maar hopen dat de leraar dit goed vind.

Luc

barthold · « **Reactie #8 Gepost op:** 19 november 2005, 16:37:47 »

Met één extra regel kan je deze functie ook als worksheetfunctie gebruiken:

Function IsBookOpen(ByVal TargetBook As String) As Boolean
On Error Resume Next
Application.Volatile
IsBookOpen = CBool(Len(Application.Workbooks(TargetBook).Name) > 0)
End Function

Volatile zorgt ervoor dat de functie telkens opnieuw wordt berekend bij een workbook refresh.

Aanroepen in een cel: =IsBookOpen("test.xls")

Tot jullie dienst,
Bart

Help!

Menu

Hulp bij posten

Zoeken

Recente topics