Penny,

Hoe kan je via een commando alle textvakken op een formulier terug leegmaken?

Gebruik daarvoor dit codeblokjePrivate Sub btn_Clear_Click()
Dim ctrl As Control

    For Each ctrl In Me.Controls
        If TypeOf ctrl Is msforms.TextBox Then ctrl.Text = ""
    Next ctrl
   
End Sub

Groet, Leo

Penny, En voor je tweede vraag heb ik alle code achter het formulier 'frm_ zoeken' herschreven. Plak dit ipv je eigen code en test ff met de 1e textbox (na invoer op enter drukken en kijk wat er gebeurt)
Dim KolomNr As Integer

Private Sub UserForm_Initialize()

     btn_Zoek.Enabled = False
       
End Sub

Private Sub AL01_BeforeUpdate(ByVal Cancel As MSForms.ReturnBoolean)
Dim ctrl As Control
Const DezeCtrl As String = "AL01"

    For Each ctrl In Me.Controls
        If TypeOf ctrl Is MSForms.TextBox And ctrl.Name <> DezeCtrl Then
            ctrl.Enabled = False
            ctrl.BackStyle = 0
        End If
    Next ctrl
   
    btn_Zoek.Enabled = True
   
End Sub

Private Sub btn_Clear_Click()
Dim ctrl As Control

    For Each ctrl In Me.Controls
        If TypeOf ctrl Is MSForms.TextBox Then
            ctrl.Text = ""
            ctrl.Enabled = True
            ctrl.BackStyle = 1
        End If
    Next ctrl
   
    btn_Zoek.Enabled = False
    Selection.AutoFilter Field:=KolomNr
   
End Sub

Private Sub btn_Zoek_Click()
Dim ctrl As Control
Dim c As Range
Dim ZoekKolom As String, FilterNaam As String

    For Each ctrl In Me.Controls
        If TypeOf ctrl Is MSForms.TextBox And ctrl.Enabled = True Then
            ZoekKolom = ctrl.Name
            FilterNaam = ctrl.Value
        End If
    Next ctrl

    On Error Resume Next
   
    With Sheets("Overzicht_").Rows(1)
        Set c = .Find(ZoekKolom)
        KolomNr = Sheets("Overzicht_").Range(c.Address).Column - 1
    End With
   
    Selection.AutoFilter Field:=KolomNr, Criteria1:=FilterNaam
   
    MsgBox KolomNr & "..." & ZoekKolom & "..." & FilterNaam
   
    On Error GoTo 0
   
End Sub

Als dit je dan bevalt, zal je voor iedere textbox op dat formulier deze sub moeten aanmakenPrivate Sub XXXX_BeforeUpdate(ByVal Cancel As MSForms.ReturnBoolean)Niet vergeten om dan de regel met de constante óók aan te passen!Const DezeCtrl As String = "XXXX" 'geef hier de juiste naam van de textbox

Groet, Leo

Penny, Aanpassen staat je vrij (logisch)! Maar de reden dat ik je zoekscherm zo gemaakt had, was omdat je dan letterlijk 1 filter krijgt.
Moet je namelijk 'ns kijken wat je nu met het filteren doet. Namelijk óók een 'for...each textbox'. WAAR wordt dan op gefilterd??? Het filteren zal ALTIJD worden opgezet op volgorde van je TextBoxen.
Voorbeeldje: als je een NAW-tabel zou willen filteren om te zoeken naar 'Meneer Oplos', dan kan het filter op 'Geslacht, Naam' een ander resultaat geven dan 'Naam, Geslacht'.

Groet, Leo